fonto-doc-load:resolve-content-reference

module namespace dita = "http://www.fontoxml.com/functions/dita";

import module namespace fonto-doc-load = "http://www.fontoxml.com/functions/document-loading";
import module namespace fonto = "http://www.fontoxml.com/functions";

declare %public function dita:resolve-dita-conref ($conrefElement as element()) as map(*) {
    let $url := $conrefElement/@conref return
    fonto-doc-load:resolve-content-reference(
         if (fn:substring-before($url, '#')) then
            fn:substring-before($url, '#')
         else if (contains($url, "#")) then
            fonto:remote-document-id($conrefElement)
         else
            $url,
        function($doc as node()) as element() {
            let $afterHash := fn:substring-after($url, '#'),
                $target := if (contains($afterHash, "/")) then
                        $afterHash => fn:substring-after("/")
                    else
                        $afterHash
            return if ($target) then $doc/descendant-or-self::*[@id = $target] else $doc
        })
};